All Answers

You can’t change the built in messabox but you can create a custom messagebox and use either ShowDialog or ShowDialogAsync. The return value is the same DialogResult.

Converting statics into session-statics is one of the first steps we do in our migration projects.

These are 3 solutions, from easier to faster.

Assuming you have:

Module Module1
    Public Name As String
End Module

Public Class Class1
    Public Sub Test()
        Module1.Name = "Test"
    End Sub
End Class

Change it to:

Module Module1
    Public Property Name As String
      Get
          Return Wisej.Web.Application.Session("Name")
      End Get
      Set(value As String)
          Wisej.Web.Application.Session("Name") = value
      End Set
    End Property
End Module

The code using Module1.Name is unchanged, Name is still shared, but it returns/gets the value from the current session.

If you have many module shared this is not  a good solution and the name in the session may conflict with other code using the session storage. So you may want to prefix the key with something. It may also be slow if you use the property many times in a request.

A better approach is to convert all shared into class variables and store the entire instance as a singleton in the session:

Module Module1
    Public ReadOnly Property Statics As StaticsWrapper
        Get
            Dim key As String = GetType(StaticsWrapper).FullName
            Dim instance As StaticsWrapper = Wisej.Web.Application.Session(key)
           If (instance Is Nothing) Then
               instance = New StaticsWrapper
               Wisej.Web.Application.Session(key) = instance
           End If
           Return instance
       End Get
    End Property

    Public Class StaticsWrapper
        Public Name As String
    End Class
End Module

The code using Module1.Name should become Module1.Statics.Name. The advantage is that you can put  many fields in StaticsWrapper and save/load only 1 instance from the session.

This last one is the same StaticsWrapper approach but it’s faster. It uses a thread static to retrieve the session static instance only once on first use.

Module Module1
    Sub New()
       AddHandler Wisej.Web.Application.ThreadBegin, AddressOf Module1_ThreadCleanUp
       AddHandler Wisej.Web.Application.ThreadEnd, AddressOf Module1_ThreadCleanUp
    End Sub

    <ThreadStatic>
    Private StaticsInstance As StaticsWrapper

    Private Sub Module1_ThreadCleanUp(sender As Object, e As EventArgs)
      StaticsInstance = Nothing
    End Sub

    Public ReadOnly Property Statics As StaticsWrapper
      Get
         If StaticsInstance Is Nothing Then
            Dim key As String = GetType(StaticsWrapper).FullName
            StaticsInstance = Wisej.Web.Application.Session(key)
            If (StaticsInstance Is Nothing) Then
               StaticsInstance = New StaticsWrapper
               Wisej.Web.Application.Session(key) = StaticsInstance
            End If
         End If
         Return StaticsInstance
      End Get
    End Property

    Public Class StaticsWrapper
       Public Name As String
    End Class
End Module

The code using Module1.Name should become Module1.Statics.Name.

Wisej.Web.Application has two events ThreadBegin and ThreadEnd that can be used to clean up the thread static when a thread starts and ends. Every request is on a new thread but the threads are reused since they come from the thread pool. That’s why we have the ThreadBegin and ThreadEnd events – to let an app (usually extensions or special implementations) manage thread statics effectively.

HTH

BTW, I didn’t test any of the code above, I tried to convert it from C#. In any case, I’m sure you get the gist of the approach and can adapt it to your app.

Thanks Frank – I had the templates and running the devenv command fixed it.

Fixed in release 1.5.48

Best regards
Frank